Shelly 4Pro in Homematic einbinden - mit der Originalfirmware

SparkyMaster

Hallo Homematic-Freunde,

endlich habe ich meinen ersten Shelly 4Pro in den Händen halten können. Gleich habe ich mich an den E-Anschluss gewagt () und ihn in Betrieb genommen. Da dies so reibungslos lief folgte promt die Einbindung in die Homematic-Welt.

Um den Shelly 4Pro in Homematic einzubinden, braucht es keine Fremdfirmware, die man flashen muß.

Nachfolgend meine Lösung mit der Originalfirmware:

techn. Voraussetzungen:

kompatibel mit den Homematic-Systemen CCU2, CCU3, Charly, sowie allen Ablegern wie RaspberryMatic und piVCCU.
installiertes Addon CUxD in aktueller Version

(Das Wissen um den Umgang CUxD, wie z.B. Geräte anlegen, setze ich an dieser Stelle voraus, sonst "explodiert" diese Anleitung. Danke für's Verständnis.)

DIe Vorteile:

alle Shelly 4Pro -Eigenschaften bleiben erhalten, da ich die Aktoren mit der originalen Herstellerfirmware betreibe
alle zukünftigen Shelly 4Pro -Aktualisierungen/ -updates werden nutzbar sein
Volle Shelly-App-Bedienbarkeit parallel zur Homematic-Automatisierung
Betrieb als lokale Lösung oder über Shelly-Cloud, zusätzlich Homematic

Folgende Funktionen habe ich auf der Homematic-Seite umgesetzt:

Anzeige des Schaltzustandes (EIN / AUS)
Anzeige / Überwachung des Onlinestatus (Erreichbarkeit im WLAN) (optional)
Anzeige / Überwachung der Leistungsanzeige in W (optional)

Die Ansicht der Anbindung:

Der Inhalt kann nicht angezeigt werden, da Sie keine Berechtigung haben, diesen Inhalt zu sehen.

Bild 1

Ich möchte Euch an dieser Stelle empfehlen, vor der Umsetzung mal einen Blick in diese Threads zu werfen:

Wichtige Hinweise zu den Shelly-Kopplungen an Homematic

Die Umsetzung:

Anzeige vom Schaltzustand:

(Auf die Beschreibung des Anlegens der CUxD-Geräte verzichte ich an dieser Stelle, dafür gibt es die CUxD-Doku!)

Falls noch nicht vorhanden, bitte ein Gerät (28) System Exec anlegen! Darüber werden die Befehle abgesetzt. (Im CUxD-Exec werden keine Eintragungen gemacht!)
-> Anleitung: CUxD-Exec-Device erstellen

Anlegen einer CUxD (40) 16-Kanal Universalsteuerung als Schalter

Der Inhalt kann nicht angezeigt werden, da Sie keine Berechtigung haben, diesen Inhalt zu sehen.

.Als Geräte-Icon kann man idealerweise einen "Schaltaktor 4fach Hutschiene" wählen.

Mit jedem Kanal des CUxD-Gerätes können dann die einzelnen 4 Kanäle des Shelly 4Pro abgebildet werden und/oder weitere Shelly 4Pro.

Die Einstellungen der Kanäle:

Der Inhalt kann nicht angezeigt werden, da Sie keine Berechtigung haben, diesen Inhalt zu sehen.

SWITCH|CMD_EXEC: Häkchen setzen !

Kanal 1:

Einstellung für SWITCH|CMD_SHORT:

Code

wget -q -O - 'http://192.168.178.43/relay/0?turn~3doff'

Einstellungen für SWITCH|CMD_LONG:

Code

wget -q -O - 'http://192.168.178.43/relay/0?turn~3don'

Kanal 2:

Einstellung für SWITCH|CMD_SHORT:

Code

wget -q -O - 'http://192.168.178.43/relay/1?turn~3doff'

Einstellungen für SWITCH|CMD_LONG:

Code

wget -q -O - 'http://192.168.178.43/relay/1?turn~3don'

Kanal 3:

Einstellung für SWITCH|CMD_SHORT:

Code

wget -q -O - 'http://192.168.178.43/relay/2?turn~3doff'

Einstellungen für SWITCH|CMD_LONG:

Code

wget -q -O - 'http://192.168.178.43/relay/2?turn~3don'

Kanal 4:

Einstellung für SWITCH|CMD_SHORT:

Code

wget -q -O - 'http://192.168.178.43/relay/3?turn~3doff'

Einstellungen für SWITCH|CMD_LONG:

Code

wget -q -O - 'http://192.168.178.43/relay/3?turn~3don'

IP-Adresse des Shelly 4Pro jeweils anpassen !

Damit ist der Shelly 4Pro schon einsatzbereit und die 4 Kanäle können ein- und ausgeschalten werden.

____________________________________________________________

Die Anleitung inkl. der Skripte und Bilder unterliegt dem Urheberrecht. Wer gegen das Urheberrecht verstößt (z.B. Bilder oder Texte unerlaubt kopiert und auf anderen Webseiten publiziert), macht sich gem. §§ 106 ff UrhG strafbar, kann zudem kostenpflichtig abgemahnt werden und muss Schadensersatz leisten (§ 97 UrhG).

SparkyMaster

Aktualisierung des Schaltstatus:

Die Aktualisierung ist wichtig, damit in Homematic der Schaltzustand auch stimmt, wenn z.B. über die Shelly-App geschaltet wird.

Falls noch nicht vorhanden, bitte ein Gerät (28) System Timer anlegen! (Im CUxD-Timer muss nur die Aktualisierungszeit gesetzt werden!)

Für die autom. Aktualisierung des Schaltstatus benötigen wir 1 Timer ...

Der Inhalt kann nicht angezeigt werden, da Sie keine Berechtigung haben, diesen Inhalt zu sehen.

Aktualisierung alle 30 Sekunden (Zeit variabel)

... der das Programm zur Aktualisierung triggert:

Der Inhalt kann nicht angezeigt werden, da Sie keine Berechtigung haben, diesen Inhalt zu sehen.

Alternativ kann auch im WENN auch auf "Timerevent" des Timers ausgelöst werden.

Fehlt nur noch das Skript für die 1. DANN-Zeile:

Code

!Skript zur Statusaktualisierung Shelly 4Pro mit Originalfirmware als 4-fach Schalter (by SparkyMaster 1.0)

!***** Schaltstatus auslesen Schalter 1 ****
!In der folgenden Zeile die IP des Shelly4Pro anpassen
var url = "http://192.168.178.43/relay/0/status";

!In den folgenden 4 Zeilen die CUxD-Exec-Geräteadresse anpassen (hier: 2801003:2)
dom.GetObject("CUxD.CUX2801003:2.CMD_SETS").State("wget -q -O - '"#url#"'");
dom.GetObject("CUxD.CUX2801003:2.CMD_QUERY_RET").State(1);
string Antwort = dom.GetObject("CUxD.CUX2801003:2.CMD_RETS").State();
dom.GetObject("CUxD.CUX2801003:2.CMD_SETS").State("0");  
!WriteLine(Antwort);

!In diesem Abschnitt NICHTS ändern
string word = "ison:";
integer word_laenge = word.Length();
integer word_position = Antwort.Find(word);
string daten = Antwort.Substr((word_position + word_laenge +4), 5);
integer word_position = daten.Find(word);
daten = daten.Substr(0, (word_position -3));
Antwort = "true";
!WriteLine(daten);

!**** Zustand Kanal 1 aktualisieren ****
!In den folgenden 3 Abschnitten die CUxD-Adresse für den Kanal1 des Shelly4Pro anpassen
var zustand = dom.GetObject("CUxD.CUX4000009:1.STATE").State();
!WriteLine(zustand);

if ((daten == "true,") && (zustand != true) )
{dom.GetObject("CUxD.CUX4000009:1.SET_STATE").State(1);
WriteLine("if ON");
}
if ((daten == "false") && (zustand != false)) {
dom.GetObject("CUxD.CUX4000009:1.SET_STATE").State(0);
WriteLine("if off");
}

!***** Schaltstatus aktualisieren Schalter 2 ****
!In der folgenden Zeile die IP des Shelly4Pro anpassen
var url = "http://192.168.178.43/relay/1/status";

!In den folgenden 4 Zeilen die CUxD-Exec-Geräteadresse anpassen (hier: 2801003:2)
dom.GetObject("CUxD.CUX2801003:2.CMD_SETS").State("wget -q -O - '"#url#"'");
dom.GetObject("CUxD.CUX2801003:2.CMD_QUERY_RET").State(1);
string Antwort = dom.GetObject("CUxD.CUX2801003:2.CMD_RETS").State();
dom.GetObject("CUxD.CUX2801003:2.CMD_SETS").State("0");  
WriteLine(Antwort);

!In diesem Abschnitt NICHTS ändern
string word = "ison:";
integer word_laenge = word.Length();
integer word_position = Antwort.Find(word);
string daten = Antwort.Substr((word_position + word_laenge +4), 5);
integer word_position = daten.Find(word);
daten = daten.Substr(0, (word_position -3));
Antwort = "true";
WriteLine(daten);

!**** Zustand Kanal 2 aktualisieren ****
!In den folgenden 3 Abschnitten die CUxD-Adresse für den Kanal2 des Shelly4Pro anpassen
var zustand = dom.GetObject("CUxD.CUX4000009:2.STATE").State();
!WriteLine(zustand);

if ((daten == "true,") && (zustand != true) )
{dom.GetObject("CUxD.CUX4000009:2.SET_STATE").State(1);
WriteLine("if ON");
}
if ((daten == "false") && (zustand != false)) {
dom.GetObject("CUxD.CUX4000009:2.SET_STATE").State(0);
WriteLine("if off");
}

!***** Schaltstatus auslesen Schalter 3 ****
!In der folgenden Zeile die IP des Shelly4Pro anpassen
var url = "http://192.168.178.43/relay/2/status";

!In den folgenden 4 Zeilen die CUxD-Exec-Geräteadresse anpassen (hier: 2801003:2)
dom.GetObject("CUxD.CUX2801003:2.CMD_SETS").State("wget -q -O - '"#url#"'");
dom.GetObject("CUxD.CUX2801003:2.CMD_QUERY_RET").State(1);
string Antwort = dom.GetObject("CUxD.CUX2801003:2.CMD_RETS").State();
dom.GetObject("CUxD.CUX2801003:2.CMD_SETS").State("0");  
!WriteLine(Antwort);

!In diesem Abschnitt NICHTS ändern
string word = "ison:";
integer word_laenge = word.Length();
integer word_position = Antwort.Find(word);
string daten = Antwort.Substr((word_position + word_laenge +4), 5);
integer word_position = daten.Find(word);
daten = daten.Substr(0, (word_position -3));
Antwort = "true";
!WriteLine(daten);

!**** Zustand Kanal 3 aktualisieren ****
!In den folgenden 3 Abschnitten die CUxD-Adresse für den Kanal3 des Shelly4Pro anpassen
var zustand = dom.GetObject("CUxD.CUX4000009:3.STATE").State();
!WriteLine(zustand);

if ((daten == "true,") && (zustand != true) )
{dom.GetObject("CUxD.CUX4000009:3.SET_STATE").State(1);
WriteLine("if ON");
}
if ((daten == "false") && (zustand != false)) {
dom.GetObject("CUxD.CUX4000009:3.SET_STATE").State(0);
WriteLine("if off");
}

!***** Schaltstatus auslesen Schalter 4 ****
!In der folgenden Zeile die IP des Shelly4Pro anpassen
var url = "http://192.168.178.43/relay/3/status";

!In den folgenden 4 Zeilen die CUxD-Exec-Geräteadresse anpassen (hier: 2801003:2)
dom.GetObject("CUxD.CUX2801003:2.CMD_SETS").State("wget -q -O - '"#url#"'");
dom.GetObject("CUxD.CUX2801003:2.CMD_QUERY_RET").State(1);
string Antwort = dom.GetObject("CUxD.CUX2801003:2.CMD_RETS").State();
dom.GetObject("CUxD.CUX2801003:2.CMD_SETS").State("0");  
!WriteLine(Antwort);

!In diesem Abschnitt NICHTS ändern
string word = "ison:";
integer word_laenge = word.Length();
integer word_position = Antwort.Find(word);
string daten = Antwort.Substr((word_position + word_laenge +4), 5);
integer word_position = daten.Find(word);
daten = daten.Substr(0, (word_position -3));
Antwort = "true";
!WriteLine(daten);

!**** Zustand Kanal 4 aktualisieren ****
!In den folgenden 3 Abschnitten die CUxD-Adresse für den Kanal4 des Shelly4Pro anpassen
var zustand = dom.GetObject("CUxD.CUX4000009:4.STATE").State();
!WriteLine(zustand);

if ((daten == "true,") && (zustand != true) )
{dom.GetObject("CUxD.CUX4000009:4.SET_STATE").State(1);
WriteLine("if ON");
}
if ((daten == "false") && (zustand != false)) {
dom.GetObject("CUxD.CUX4000009:4.SET_STATE").State(0);
WriteLine("if off");
}


daten = "0";

!Ende Skript

Alles anzeigen

Gemäß den Hinweisen im Skript sind anzupassen:

IP des Shelly 4Pro

CUxD-Exec-Kanal

CUxD-Kanal des Shelly 4Pro

Nun wird der Schaltzustand des Shelly 4Pro auch in Homematic aktualisiert, wenn über die App oder Shelly-Szenen geschaltet wird.

____________________________________________________________

Die Anleitung inkl. der Skripte und Bilder unterliegt dem Urheberrecht. Wer gegen das Urheberrecht verstößt (z.B. Bilder oder Texte unerlaubt kopiert und auf anderen Webseiten publiziert), macht sich gem. §§ 106 ff UrhG strafbar, kann zudem kostenpflichtig abgemahnt werden und muss Schadensersatz leisten (§ 97 UrhG).

SparkyMaster

Optionale Anzeigen:

1. Onlinestatus:

Die optinale Anzeige des Onlinestatus erfolgt wie bei allen anderen Kopplungen auch mittels Systemvariable und CUxD-Ping-Gerät(28) .

Für die Anzeige des Onlinestatus wird 1 Systemvariable benötigt:

Der Inhalt kann nicht angezeigt werden, da Sie keine Berechtigung haben, diesen Inhalt zu sehen.

Die Variable wird wieder mit dem entsprechenden Kanal des CUxD-Gerät verknüpft und somit dort angezeigt.

Den Onlinestatus überwacht und steuert ein CUxD-Ping Kanal. D.h. mit 1 CUxd-Ping-Gerät (28) können bis zu 16 Shelly 4Pro überwacht werden. Natürlich kann auch ein freier Kanal eines schon vorhandenen CUxD-Ping genutzt werden.

Falls noch nicht vorhanden, bitte ein Gerät (28) System Ping/Alive anlegen!

Der Inhalt kann nicht angezeigt werden, da Sie keine Berechtigung haben, diesen Inhalt zu sehen.

IP anpassen!

Einstellungen für SWITCH|CMD_EXEC_TRUE:

Code

extra/timer.tcl Onlinestatus_Shelly4Pro 1

Einstellungen für SWITCH|CMD_EXEC_FALSE:

Code

extra/timer.tcl Onlinestatus_Shelly4Pro 0

Name der Systemvariablen jeweils anpassen! (hier: Onlinestatus_Shelly4Pro)

Im eingestellten Intervall des Timers wird nun der Onlinestatus aktualisiert.

2. aktuelle Leistungsanzeige:

wertet die Leistung jedes Shelly 4Pro-Kanals aus, zeigt sie im CUxD-Gerät an und natürlich kann der Wert auch in Programmen genutzt werden.

Dazu brauchen wir 4 Systemvariable für den aktuellen Leistungswert:

Der Inhalt kann nicht angezeigt werden, da Sie keine Berechtigung haben, diesen Inhalt zu sehen.

Die Variablen werden dem entsprechenden Kanal des Shelly-CUxD-Gerätes zugeordnet. Dadurch werden sie wie im Bild 1 in #1 sichtbar.

In das Programm zur Statusaktualisierung (siehe Bild in #2) fügen wir nun eine 2. DANN Zeile zur Aktualisierung der Leistungsdaten ein.

Achtung:

Die Namen der Systemvariablen dürfen keine Leerzeichen und keine Umlaute enthalten!

Das Skript dazu:

Code

!Skript V1.1 zur Leistungsaktualisierung des Shelly 4Pro mit Originalfirmware (c)2020 by SparkyMaster

!***********************************************************************

!Ein Dank an alchy aus dem Homematic-Forum. Ich setze zur Auswertung einen von Ihm veröffentlichten Code mit ein, den ich mit genialer Hilfe von 66er (auch hier mein Dank!) angepasst habe.

!Quelle des Originalcode:https://homematic-forum.de/for…&t=43632&p=435194#p435194

!***********************************************************************


!Raumbezeichnung (nur zur Orientierung, ggf anpassen)



!**** SETUP ******** SETUP ******** SETUP ******** SETUP ***


! ACHTUNG: Beim Anpassen der Adressen keine "" löschen!


! Setup der CUxD-GERÄTE

var url = "http://192.168.178.43/status"; ! IP-Adresse des Shelly 4Pro anpassen

var execta = "CUxD.CUX2801003:2"; ! Adresse und Kanal des CUxD-Exec-Device angeben



!Setup der SYSTEMVARIABLEN


var power0 = "Shelly_4Pro_Leistung1"; !Name der Systemvariablen anpassen

var power1 = "Shelly_4Pro_Leistung2"; !Name der Systemvariablen anpassen

var power2 = "Shelly_4Pro_Leistung3"; !Name der Systemvariablen anpassen

var power3 = "Shelly_4Pro_Leistung4"; !Name der Systemvariablen anpassen




!Setup Anzahl Kanal

var anzahls = "4" ; ! erlaubt sind die Zahlen 1 bis 4


!****ENDE SETUP ********ENDE SETUP ********ENDE SETUP ******



!*****Ab hier NICHTS MEHR ÄNDERN *****



!****Abfrage des Shelly 4Pro****


dom.GetObject(""#execta#".CMD_SETS").State("wget -q -O - '"#url#"'");

dom.GetObject(""#execta#".CMD_QUERY_RET").State(1);

string Antwort = dom.GetObject(""#execta#".CMD_RETS").State();

string p = dom.GetObject(""#execta#".CMD_RETS").State();

dom.GetObject(""#execta#".CMD_SETS").State("0");


!WriteLine(Antwort);



!JSON String nach Vorgaben auslesen

! v0.2 (c) by Alchy und angepasst von SparkyMaster (mit genialer Hilfe von 66er)

string output = Antwort;

!WriteLine(output);

string part; string code;string slist;integer collect = -1;

foreach (part, output.Split("{")){

collect = part.Find("power");

if (collect>-1){

code = ((part.StrValueByIndex(",",0)).StrValueByIndex(":",1));

code = code.Substr(0, code.Length()-1);

slist = slist#code#"/";

}}

!WriteLine(slist);


! Ergebnis in Einzelwerte auflösen

var p1 = slist.StrValueByIndex("/", 4);

var p2 = slist.StrValueByIndex("/", 5);

var p3 = slist.StrValueByIndex("/", 6);

var p4 = slist.StrValueByIndex("/", 7);


!WriteLine(p1);

!WriteLine(p2);

!WriteLine(p3);

!WriteLine(p4);




!Werte in Systemvariablen schreiben


dom.GetObject(""#power0#"").State(p1);

if ((anzahls) == 1) { quit; };


dom.GetObject(""#power1#"").State(p2);

if ((anzahls) == 2) { quit; };


dom.GetObject(""#power2#"").State(p3);

if ((anzahls) == 3) { quit; };

dom.GetObject(""#power3#"").State(p4);


!WriteLine("Skript beendet")


!Ende Skript

Alles anzeigen

Gemäß den Hinweisen im Skript sind anzupassen:

IP des Shelly 4Pro

CUxD-Exec-Kanal

Systemvariablen

Im eingestellten Intervall des Timers wird nun die aktuelle Leistung aktualisiert.

Viel Erfolg !

____________________________________________________________

Die Anleitung inkl. der Skripte und Bilder unterliegt dem Urheberrecht. Wer gegen das Urheberrecht verstößt (z.B. Bilder oder Texte unerlaubt kopiert und auf anderen Webseiten publiziert), macht sich gem. §§ 106 ff UrhG strafbar, kann zudem kostenpflichtig abgemahnt werden und muss Schadensersatz leisten (§ 97 UrhG).

Gast10

immer wieder gerne.

jungloewe

Zitat von SparkyMaster

©2020 SparkyMaster - ausführlicher Hinweis dazu am Ende der Anleitung

Aktualisierung des Schaltstatus:

Besten Dank für das Skript!

hier mal eine vereinfachte Version, in der man nur im Kopf die Konfigurationen vornehmen muss:

Code

!geänderte version von @jungloewe am 03.06.22, basiert auf:
!Skript zur Statusaktualisierung Shelly 4Pro mit Originalfirmware als 4-fach Schalter (by SparkyMaster 1.0)

!*************************************************************************************
!***** Ab hier die persönlichen Einstellungen vornehmen:
!*****
!***** IP des Shelly ****
string ip = "192.168.178.175";
!***** CUxD-Exec-Geräteadresse ****
string cuxd = "CUX2801002:2";
!***** Schalteradressen des Shelly ****
string list = ("CUX4000004:13\tCUX4000004:14\tCUX4000004:15\tCUX4000004:16");
!*************************************************************************************

string obj;         ! Kanalvariable
integer idx = 0;    ! Indexvariable

!WriteLine("Kanalliste: "#list)

foreach (obj, list) { 
  !***** Schaltstatus auslesen Schalter n ****
  var url = "http://"#ip#"/relay/"#idx#"/status";

  dom.GetObject("CUxD."#cuxd#".CMD_SETS").State("wget -q -O - '"#url#"'");
  dom.GetObject("CUxD."#cuxd#".CMD_QUERY_RET").State(1);
  string Antwort = dom.GetObject("CUxD."#cuxd#".CMD_RETS").State();
  dom.GetObject("CUxD."#cuxd#".CMD_SETS").State("0");  
  !WriteLine("Antwort:"#Antwort);

  string word = "ison:";
  integer word_laenge = word.Length();
  integer word_position = Antwort.Find(word);
  boolean daten = Antwort.Substr((word_position + word_laenge +5), 5).StartsWith("true");

  !**** Zustand des Kanals erkennen ****
  boolean zustand = dom.GetObject("CUxD."#obj#".STATE").State();
  WriteLine("Soll "#idx#":  '"#daten#"' / Ist: '"#zustand#"'");

  !**** Bei Bedarf aktualisieren ****
  if ((daten == true) && (zustand == false)) {
    dom.GetObject("CUxD."#obj#".SET_STATE").State(1);
    WriteLine("Set ON");
  }
  if ((daten == false) && (zustand == true)) {
    dom.GetObject("CUxD."#obj#".SET_STATE").State(0);
    WriteLine("Set off");
  }
  
  idx = idx+1;
}

!Ende Skript

Alles anzeigen

Shelly 4Pro in Homematic einbinden - mit der Originalfirmware

SparkyMaster 2. Juni 2020 um 17:23

Tags