Shelly Door/Window2 in Homematic einbinden - mit der Originalfirmware ab V1.8.0

! Skripterweiterung neo-v1.1.7 zur Statusauswertung Shelly DW2 ab Firmware v1.8.0 (c) 2020 by neo-v (alias Maik)
! Dieses Skript basiert auf @66er (alias Stefan.K) seinem Skript siehe unten
! Änderungen Zusatz: an DW2 angepasst, Ping, Temperatur und Zustand Licht abfrage und Auswertung
! Skript V3.1.3 zur Statusaktualisierung ShellyDoor Window mit Originalfirmware (c) 2020 by 66er  (alias Stefan.K)
! für Shelly D/W ab Firmware 1.6.x mit Kippwinkel und Vibrationsalarm, NEZ: Variablen einzeln aktivierbar, ob vorhanden
! Raumbezeichnung WZ    Raum  (kann angepasst werden)


!**** SETUP ******** SETUP ******** SETUP ******** SETUP ***

! Setup der CUxD-GERÄTE
var url = "http://192.168.178.106/status"; !  IP-Adresse des Shelly Door Window2 anpassen 
var urlp = "192.168.178.106";               ! gleiche IP-Adresse Shelly Door Window2 im Format 192.168.xxx.xxx
var exec = "CUxD.CUX2801001:14";   ! Adresse und Kanal des CUxD-Exec-Device angeben! Skript Zusatz, Überprüfung ob Gerät Online ist
var shelly =  "CUxD.CUX4000085:2" ;  ! Adresse und Kanal des CUxD-Device für den Shelly D/W anpassen


!Setup der SYSTEMVARIABLEN
var mkbat = "106_Bat";                     ! Name der Systemvariablen anpassen, "" bleiben stehen
var mklux = "106_Lux";                     ! Name der Systemvariablen anpassen, "" bleiben stehen
var mktil = "106_Winkel";                 ! Name der Systemvariablen anpassen, "" bleiben stehen
var mkvib = "106_Vibration";            ! Name der Systemvariablen anpassen, "" bleiben stehen
var mktemp = "106_Temp";              ! Name der Systemvariablen anpassen, "" bleiben stehen
var mkstatus = "106_Zustand";        ! Name der Systemvariablen (als Werteliste anpassen), "" bleiben stehen

!Setup der aktiven Variablen
!Wer nicht alle Variablen umsetzt, muß diese hier auf "0" setzen
var amkping = "1";                   ! Ping auswerten, mögliche Werte: 0 für Nein oder 1 für Ja
var amktilt = "1";                      ! Kippwinkel auswerten, mögliche Werte: 0 für Nein oder 1 für Ja
var amkvib = "1";                     ! Vibrationsalarm auswerten, mögliche Werte: 0 für Nein oder 1 für Ja
var amklux = "1";                     ! Helligkeit auswerten, mögliche Werte: 0 für Nein oder 1 für Ja
var amkbat = "1";                     ! Bat auswerten, mögliche Werte: 0 für Nein oder 1 für Ja
var amktemp = "1";                  ! Temp auswerten, mögliche Werte: 0 für Nein oder 1 für Ja
var amkstatus = "1";                ! Status Licht auswerten, mögliche Werte: 0 für Nein oder 1 für Ja

! ########################################################
! ########################################################
!  ****ENDE SETUP ********ENDE SETUP ********ENDE SETUP ******
! ########################################################
!*****Ab hier NICHTS MEHR ÄNDERN *****
! ########################################################



! ############# Ping senden ########################

string stderr;
 string stdout;
 integer Auslese;
 system.Exec("ping -c 1 '"#urlp#"'", &stdout, &stderr);
 Auslese = stdout.Find("ms");

!WriteLine(urlp);
!WriteLine(Auslese);

! ###### Ping Ergebnis auswerten und bei negativ Quit Skript ausführen #########

if ((amkping) == 1 ) {if ((Auslese) == -1) { quit; };}

! #####################################################
! ##### wenn der Ping positiv ist, geht das Skript weiter ###################
! #####################################################

dom.GetObject(""#exec#".CMD_SETS").State("wget -q -O - '"#url#"'");
dom.GetObject(""#exec#".CMD_QUERY_RET").State(1);
string Antwort = dom.GetObject(""#exec#".CMD_RETS").State();
string tc = Antwort;
string t = Antwort;
string lu = Antwort;
string vi = Antwort;
dom.GetObject(""#exec#".CMD_SETS").State("0");  

!WriteLine(Antwort);

!***Auswertung MK ****
string word = "state";
integer word_laenge = word.Length();
integer word_position = Antwort.Find(word);
string daten = Antwort.Substr((word_position + word_laenge +3), 4);
integer word_position = daten.Find(word);
daten = daten.Substr(0, (word_position -3));
Antwort = "true";
!WriteLine(daten);


!Auswertung MK
var zustand = dom.GetObject(""#shelly#".STATE").State();
!WriteLine(zustand);
if ((daten == "clos") && (zustand != false) )
{dom.GetObject(""#shelly#".SET_STATE").State(0);
!WriteLine("if ON");
}
if ((daten == "open") && (zustand != true))
{dom.GetObject(""#shelly#".SET_STATE").State(1);
!WriteLine("if off");
}


!****Auswertung des Antwortstrings für Batt  ****
string b;
foreach (b,t.Split (",")) {
   if (b.LTrim ("{").StartsWith ('"bat"')) {
   string bat =  (b.StrValueByIndex (":",2).RTrim ("}"));
! WriteLine(bat);
   }
}  


!**** Variable setzen****
if ((amkbat) == 1 ) {dom.GetObject(""#mkbat#"").State(bat);}


!****Auswertung des Antwortstrings für Lux  ****

string l;
foreach (l,t.Split (",")) {
   if (l.LTrim ("{").StartsWith ('"lux"')) {
   string lux =  (l.StrValueByIndex (":",2).RTrim ("}"));
! WriteLine(lux);
   }
}  

!**** Variable setzen****
if ((amklux) == 1 ) {dom.GetObject(""#mklux#"").State(lux);}

! ########################################################
! ########################################################
!             ****Auswertung des Antwortstrings für Kippwinkel ****
! ########################################################
! ########################################################

string output = t;
!WriteLine(output);
string part; string code;string slist;integer collect = -1;
foreach (part, output.Split(",")){
collect = part.Find("accel");
if (collect>-1){
code = ((part.StrValueByIndex(",",0)).StrValueByIndex(":",2));
code = code.Substr(0, code.Length());
slist = slist#code#"/";
}}

!WriteLine(slist);
var tilt = slist.StrValueByIndex("/", 0);
!WriteLine(tilt);
real tr = tilt.ToFloat();
!WriteLine(tr);


!**** Variable setzen****
if ((amktilt) == 1 ) {dom.GetObject(""#mktil#"").State(tr);}


! ##################################################
! ##################################################
! #############   Auswertung Virbrationsalarm ##################
! ##################################################

string word = "vibration";
integer word_laenge = word.Length();
integer word_position = vi.Find(word);
string vilist = vi.Substr((word_position + word_laenge +2), 1);
integer word_position = vilist.Find(word);
vilist = vilist.Substr(0, (word_position -1));
!Antwort = "true";
!WriteLine(vilist);

!Variable setzen
if ((amktemp) == 1 ) {dom.GetObject(""#mkvib#"").State(vilist);}

! #######################################################
! ############### Temperatur  ermitteln ##########################
! #######################################################

string w;
foreach (w,tc.Split (",")) {
  if (w.LTrim ("{").StartsWith ('"tC"')) {
   string temp =  (w.StrValueByIndex (":",1).RTrim ("}"));
!  WriteLine(temp);
  }
}

!**** Variable setzen****
if ((amktemp) == 1 ) {dom.GetObject(""#mktemp#"").State(temp);}

! ########################################################
! #########Zustand Licht vom DW2 ermitteln ###########################
! ########################################################

string part; string code;string zlist;integer collect = 1;
foreach (part, lu.Split("{")){
collect = part.Find('"illumination"');
if (collect>-1){
code = ((part.StrValueByIndex(",",1)).StrValueByIndex(":",1));
code = code.Substr(2, code.Length()-3);
zlist = zlist#code#"/";
 }
}

!WriteLine(zlist);

! #### Zustand Licht vom DW2 auswerten und in SV schreiben ##############

var Zustand1 = zlist.StrValueByIndex("/", 0);
!WriteLine(Zustand1);
var wert1 = 0;
if(Zustand1  == "dark") {
   wert1 = 2;
 }
if(Zustand1  == "twilight") {
   wert1 = 1;
 }
if(Zustand1  == "bright") {
   wert1 = 0;
 }

!WriteLine(wert1);

! ###### Wert1 also der Zustand wird in SV als Werteliste übertragen ########
if ((amkstatus) == 1 ) {dom.GetObject(""#mkstatus#"").State(wert1);}


daten = "0";


!Ende Skript